Dfyjkt

I am trying to use vba to combine the text, table and picture into a word file from excel file. The below code works most of time. However, error 462 appears occasionally.

I searched around. Some comments said it appears because the unqualified references exist. However, I don't know what and where the unqualified reference is. A weird thing: usually the first running is ok. After that, this error usually appears in the even times, only. I am sure I closed the word file every time, no matter whether the code executes successfully or not.

Here is the code. I put the comment to indicate the line where the error occurs.

Dim WordApp As Object, WordDoc As Object

Set WordApp = New Word.Application

With WordApp
 .Visible = True

 Set WordDoc = .Documents.Add
 .ActiveDocument.Select
 With .Selection
 'narrative
 Sheet3.Range("G2").Copy
 .PasteExcelTable False, False, False

 'IO
 Sheet2.Range("A1","B11").Copy
 .PasteExcelTable False, False, False
 WordDoc.Tables(1).Columns(1).Width = InchesToPoints(1.5) 'Error 462 appears periodically on this line
 WordDoc.Tables(1).Columns(2).Width = InchesToPoints(4.5)
 WordDoc.Tables(1).Rows.Height = 20

 'HMI
 Sheet9.Range("A4").Copy
 .PasteExcelTable False, False, False
 Sheet9.Shapes("Group_Htr").Copy
 .PasteSpecial 
 .ShapeRange(1).WrapFormat.Type = wdWrapInline
 .EndKey unit:=wdStory
 'P&ID
 .TypeParagraph
 .InsertBreak Type:=wdSectionBreakNextPage
 With .PageSetup
 .LineNumbering.Active = False
 .Orientation = wdOrientPortrait
 .TopMargin = InchesToPoints(1)
 .BottomMargin = InchesToPoints(1)
 .LeftMargin = InchesToPoints(1)
 .RightMargin = InchesToPoints(1)
 .Gutter = InchesToPoints(0)
 .HeaderDistance = InchesToPoints(0.5)
 .FooterDistance = InchesToPoints(0.5)
 .PageWidth = InchesToPoints(11)
 .PageHeight = InchesToPoints(17)
 .FirstPageTray = wdPrinterDefaultBin
 .OtherPagesTray = wdPrinterDefaultBin
 .SectionStart = wdSectionNewPage
 .OddAndEvenPagesHeaderFooter = False
 .DifferentFirstPageHeaderFooter = False
 .VerticalAlignment = wdAlignVerticalTop
 .SuppressEndnotes = False
 .MirrorMargins = False
 .TwoPagesOnOne = False
 .BookFoldPrinting = False
 .BookFoldRevPrinting = False
 .BookFoldPrintingSheets = 1
 .GutterPos = wdGutterPosLeft
 If .Orientation = wdOrientPortrait Then
 .Orientation = wdOrientLandscape
 End If
 End With
 Sheet10.Range("A4").Copy
 .PasteExcelTable False, False, False
 Sheet10.Shapes("Group_Htr").Copy
 .PasteSpecial 'Error 4198 appears occasionally on this line
 End With
 .Activate

End With

The reason you get the error is because InchesToPoints is not part of Excel, which is where the code is running. This method is specific to Word, so it requires a reference to the Word.Application. Put a . in front of each occurrence so that it picks up WordApp from the With:

WordDoc.Tables(1).Columns(1).Width = .InchesToPoints(1.5)